repositories {
    maven { url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/' }
    maven { url = 'https://repo.extendedclip.com/content/repositories/placeholderapi/' }
    maven { url = 'https://jitpack.io' }
}
dependencies {
    implementation project(':common')
    implementation project(':api')
    implementation project(':bluemap')
    implementation 'com.google.code.gson:gson:2.10.1'
    compileOnly 'org.spigotmc:spigot-api:1.20.1-R0.1-SNAPSHOT'
    // Optional integrations: the plugin detects these at runtime and works without them.
    compileOnly 'net.luckperms:api:5.4'
    compileOnly 'me.clip:placeholderapi:2.11.6'
    compileOnly('com.github.MilkBowl:VaultAPI:1.7.1') { exclude group: 'org.bukkit' }
}
processResources {
    inputs.property 'version', project.version
    filesMatching('plugin.yml') { expand(version: project.version) }
}
jar {
    archiveBaseName = 'scopenet-paper'
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    from project(':common').sourceSets.main.output
    from project(':api').sourceSets.main.output
    from project(':bluemap').sourceSets.main.output
    from { configurations.runtimeClasspath.findAll { it.name.endsWith('.jar') && !it.name.startsWith('common-') && !it.name.startsWith('api-') && !it.name.startsWith('bluemap-') }.collect { zipTree(it) } }
    exclude 'META-INF/*.SF', 'META-INF/*.RSA', 'META-INF/*.DSA'
}